function EntryPage::print_comment(Comment c) {
  var string date = $c->time_display("short", "");
  var string datetime;
  $datetime = $date;

  var string symb;
  if ($c.metadata{"picture_keyword"}!=""){
    $symb = ": ";
  }
  
  var string picword;
  if (defined $c.userpic and $*comment_userpic_style !="off") {
    $picword = $c.poster.name + $symb + $c.metadata{"picture_keyword"};
  }

  var string subjecticon;
  if (defined $c.subject_icon) {
    $subjecticon = """<img src="$c.subject_icon.url" width="$c.subject_icon.width" height="$c.subject_icon.height" height="$c.userpic.height" title='$picword'/>""";
  }

  var string ip;
  if ($c.metadata{"poster_ip"}) { 
    $ip = """ &nbsp;  """ + $c.metadata{"poster_ip"}; 
  }

  var string poster = defined $c.poster ? $c.poster->as_string() : "<b>(Anonymous)</b>";

  var string pic;
  if (defined $c.userpic and $*comment_userpic_style != "off") {
    $pic = """<div class="userpic3"><img src="$c.userpic.url" width="$c.userpic.width" height="$c.userpic.height" height="$c.userpic.height" title='$picword'/></div>""";
  }

  var string indent = ($c.depth - 1) * 20 + "px";
  """
  <a name="$c.anchor"></a>
  <div class="comments">
   <div class="commentbody" style="margin-left: $indent;">
    $pic
     <div class="commentsubject">$subjecticon $c.subject</div>
   <div class="commentinfo">
   <span style="float: right; margin: 4px;"> 
""";
if ($.multiform_on) {
    """<label for="ljcomsel_$c.talkid">$*text_multiform_check</label> """; 
    $c->print_multiform_check();
  }
"""
   </span>
    <div class="postedby">$poster <span class="ip">$ip</span></div>
     <b>Posted:</b> $datetime </div>
     <div class="commtext">
       <p>"""; $c->print_text(); """</p>
     </div>
     <div class="clear">&nbsp;</div>
      <div class="commentlinks">
  """;
  var string   link_separator = ""; # separator for links
  
  # initialize array/hashes
  var string[] link_keyseq    = [""];
  var string{} link_url       = {"" => ""};
  var string{} link_caption   = {"" => ""};
  var string{} link_image     = {"" => ""};
  
  var string print           = ""; 
  var int    keyseq_index    = 0;         # set index point for new link_keyseq array
  
   # gather current linkbar
   foreach var string link_key ($c.link_keyseq) {
    var Link  link            = $c->get_link($link_key);
    $link_url{$link_key}      = $link.url;
    $link_caption{$link_key}  = $link.caption;
    $link_image{$link_key}    = $link.icon.url;
    $link_keyseq[$keyseq_index++] = $link_key; # add this to new link_keyseq array
}

  $link_image{"watch_thread"}     = "";
  $link_image{"unwatch_thread"}   = "";
  $link_image{"watching_parent"}  = "";
  $link_image{"screen_comment"}   = "";
  $link_image{"unscreen_comment"} = "";
  $link_image{"freeze_thread"}    = "";
  $link_image{"unfreeze_thread"}  = "";
  $link_image{"delete_comment"}   = "";
  $link_image{"edit_comment"}     = "";

  $link_caption{"watch_thread"}    = "Track";
  $link_caption{"unwatch_thread"}  = "Untrack";
  $link_caption{"watching_parent"} = "Watching";
  $link_caption{"screen_comment"} = "Screen";
  $link_caption{"unscreen_comment"} = "Unscreen";
  $link_caption{"freeze_thread"} = "Freeze";
  $link_caption{"unfreeze_thread"} = "Unfreeze";
  $link_caption{"delete_comment"} = "Delete";
  $link_caption{"edit_comment"} = "Edit";
  
  var string replyurl;
  if ($c.frozen) {
    $replyurl = """ &nbsp; $*text_comment_frozen &nbsp; """;
  } else {
    $replyurl = """<a href="$c.reply_url" border="0"> $*text_comment_reply &nbsp; </a> $link_separator""";
  }
  print $replyurl;
	
  # loop thru linkbar and add links to print var
  foreach var string link_key ($link_keyseq) {
    # if we can do performed action, url will be present
    if($link_url{$link_key} != "") {
      $print = $print + """<a href="$link_url{$link_key}"> &nbsp; """;
      # if image url available, use it
      if($link_image{$link_key} != "") {
        $print = $print + """<img src="$link_image{$link_key}" alt="$link_caption{$link_key}" title="$link_caption{$link_key}" align="top" border="0" />&nbsp;$link_caption{$link_key}""";
      } else {
        # else, just use text
        $print = $print + "$link_caption{$link_key}";
      }
      # add a seperator
      $print = $print + " &nbsp; </a>$link_separator";
    }
  }

  # we're done! let's print it!
  print $print;
  
  var string parent;
  var string thread;
  if($c.parent_url != "") {
    $parent = """$link_separator <a href="$c.parent_url" border="0"> $*text_comment_parent &nbsp; </a>""";
  }
  if($c.thread_url != "") {
    $thread = """$link_separator <a href="$c.thread_url" border="0"> $*text_comment_thread &nbsp; </a>""";
  }
  
  """
  <a href="$c.permalink_url" border="0"> $*text_permalink &nbsp; </a>$parent$thread
  </div></div>
  """;
  if ((size $c.replies) > 0 and $c.replies[0].full == false) {
    """<div style="margin-top: 5px; margin-bottom: 5px; clear: both;">\n""";
    $this->print_comments($c.replies);
    "</div>\n";
  }
  """
  </div><div class="clear">&nbsp;</div>
  """;
  if ((size $c.replies) > 0 and $c.replies[0].full == true) {
    $this->print_comments($c.replies);
  }
}